https://wwui.lanzouj.com/ioyWc1d4qbxe

[@Mir2m2地图收益脚本NPC]

{

#IF

CHECKLEVELEX > 0

#ACT

MOV P9 <$GLOBAL(地图收益数量)>

#IF

SMALL P9 20000001

#ACT

MUL P9 $(地图收益比例)

DIV P9 100

#ELSEACT

DIV P9 100

MUL P9 $(地图收益比例)

#IF

SMALL P9 1

#ACT

MOV P9 0

#IF

CHECKLEVELEX > 0

#SAY

<COLOR=$00B317E3 —————————————————————————————>\

<COLOR=clFuchsia 详细规则：><COLOR=$00A55200 每天晚上22:30准时举行，关门时间22:50！>\

　　　　　<COLOR=$00A55200 22:50-23:59分可申请获胜，超时自动判为无行会胜出！>\

<COLOR=clFuchsia 进入要求：><COLOR=$004A8452 参加者必须达到43级、并且是行会成员>\

<COLOR=clFuchsia 获胜奖励：><COLOR=$00006BEF 获胜行会成员所有元宝地图半价传送！>\

　　　　　<COLOR=$00006BEF 行会老大可领取元宝地图传送费用$(地图收益比例)%的收益！>\

<COLOR=clFuchsia 获胜行会：><COLOR=clTeal 【><$GLOBAL(地图收益行会)><COLOR=clTeal 】　　当前地图收益为：><$STR(P9)> <COLOR=clTeal 元宝>\

<COLOR=$00B317E3 —————————————————————————————>\

<参加行会争霸/@Mir2m2地图收益参赛>　　<行会老大领取收益/@Mir2m2地图收益领奖>　　<行会申请获胜/@Mir2m2地图收益获胜>\

[@Mir2m2地图收益参赛]

#IF

CHECKVAR GLOBAL 地图收益判断 < 1

#ACT

messagebox 对不起，行会争霸还没有开始！

GOTO @Mir2m2地图收益脚本NPC

BREAK

#IF

CHECKVAR GLOBAL 地图收益判断 = 1

#ELSEACT

messagebox 对不起，行会争霸已经关门，请等待地图内的行会分出胜负！

BREAK

#IF

CHECKLEVELEX < 43

#ACT

messagebox 对不起，你的等级未达到43级，无法进入地图！

BREAK

#IF

HAVEGUILD

#ELSEACT

MESSAGEBOX 对不起，你并没有加入行会，无法进入地图！

BREAK

#IF

ISONMAP Mir2m2_SHOUYI

#ACT

MESSAGEBOX 对不起，你已在行会争霸地图！

BREAK

#ELSEACT

MAPMOVE Mir2m2_SHOUYI

SENDMSG 0 【<$GUILDNAME>】行会的【<$USERNAME>】进入行会争霸地图！ 253 255

[@Mir2m2地图收益获胜]

#IF

CHECKVAR GLOBAL 地图收益判断 < 1

#ACT

messagebox 对不起，行会争霸还没有开始！

GOTO @Mir2m2地图收益脚本NPC

BREAK

#IF

CHECKVAR GLOBAL 地图收益判断 = 2

#ELSEACT

messagebox 对不起，请等待关门后才能申请获胜！

GOTO @Mir2m2地图收益脚本NPC

BREAK

#IF

ISONMAP Mir2m2_SHOUYI

#ELSEACT

messagebox 对不起，你不在行会争霸地图内，无法申请获胜！

GOTO @Mir2m2地图收益脚本NPC

BREAK

#IF

HAVEGUILD

#ELSEACT

MESSAGEBOX 对不起，你并没有加入行会，无法申请获胜！

GOTO @Mir2m2地图收益脚本NPC

BREAK

#IF

IsSameGuildOnMap Mir2m2_SHOUYI

#ELSEACT

MESSAGEBOX 对不起，本地图内所有人都是同一行会才能申请获胜！

GOTO @Mir2m2地图收益脚本NPC

BREAK

#IF

CHECKLEVELEX > 0

#ACT

CLOSE

CALCVAR GLOBAL 地图收益行会 = <$GUILDNAME>

SAVEVAR GLOBAL 地图收益行会 ..\QuestDiary\Mir2m2开区清空文本(免费脚本群.347979)\Mir2m2地图收益变量.txt

GMEXECUTE $(地图收益触发) @Mir2m2地图收益结束清人

SENDMSG 0 恭喜【<$GUILDNAME>】行会获得本次行会争霸的胜利，所有行会成员传送元宝地图半价！ 253 255

BREAK

[@Mir2m2地图收益领奖]

#IF

HAVEGUILD

#ELSEACT

MESSAGEBOX 对不起，你并没有加入行会！

GOTO @Mir2m2地图收益脚本NPC

BREAK

#IF

CHECKVAR GLOBAL 地图收益行会 = 

#ACT

MESSAGEBOX 对不起，您的行会不是获胜行会！\　\当前还没有获胜行会！

GOTO @Mir2m2地图收益脚本NPC

BREAK

#IF

CHECKVAR GLOBAL 地图收益行会 = <$GUILDNAME>

#ELSEACT

MESSAGEBOX 对不起，您的行会不是获胜行会！\　\当前获胜行会是：<$GUILDNAME>

GOTO @Mir2m2地图收益脚本NPC

BREAK

#IF

ISGUILDMASTER

#ELSEACT

MESSAGEBOX 对不起，您不是行会老大，无法领取收益！

GOTO @Mir2m2地图收益脚本NPC

BREAK

#IF

CHECKLEVELEX > 0

#ACT

MOV P9 <$GLOBAL(地图收益数量)>

#IF

SMALL P9 20000001

#ACT

MUL P9 $(地图收益比例)

DIV P9 100

#ELSEACT

DIV P9 100

MUL P9 $(地图收益比例)

#IF

SMALL P9 1

#ACT

MESSAGEBOX 对不起，当前地图收益为0，无法领取！

GOTO @Mir2m2地图收益脚本NPC

BREAK

#IF

CHECKLEVELEX > 0

#ACT

CALCVAR GLOBAL 地图收益数量 = 0

SAVEVAR GLOBAL 地图收益数量 ..\QuestDiary\Mir2m2开区清空文本(免费脚本群.347979)\Mir2m2地图收益变量.txt

GAMEGOLD + <$STR(P9)>

SENDMSG 0 恭喜【<$GUILDNAME>】行会老大【<$USERNAME>】领取了地图收益<$STR(P9)>元宝！ 253 255

[@Mir2m2地图收益常量加载]

#CALL [\Mir2m2地图收益配置(免费脚本群.347979)\Mir2m2地图收益常量.ini] @Mir2m2地图收益常量

}

[@Mir2m2地图收益脚本RM]

{

#IF

EQUAL I21 347979

#ELSEACT

MOV I21 347979

VAR Integer GLOBAL 地图收益判断

VAR String  GLOBAL 地图收益行会

VAR Integer GLOBAL 地图收益数量

LOADVAR GLOBAL 地图收益判断 ..\QuestDiary\Mir2m2开区清空文本(免费脚本群.347979)\Mir2m2地图收益变量.txt

LOADVAR GLOBAL 地图收益行会 ..\QuestDiary\Mir2m2开区清空文本(免费脚本群.347979)\Mir2m2地图收益变量.txt

LOADVAR GLOBAL 地图收益数量 ..\QuestDiary\Mir2m2开区清空文本(免费脚本群.347979)\Mir2m2地图收益变量.txt

[@Mir2m2地图收益开始]

#ACT

CALCVAR GLOBAL 地图收益判断 = 1

CALCVAR GLOBAL 地图收益行会 = 

SAVEVAR GLOBAL 地图收益判断 ..\QuestDiary\Mir2m2开区清空文本(免费脚本群.347979)\Mir2m2地图收益变量.txt

SAVEVAR GLOBAL 地图收益行会 ..\QuestDiary\Mir2m2开区清空文本(免费脚本群.347979)\Mir2m2地图收益变量.txt

SENDMSG 0 【行会争霸】活动已经开始，请各大行会速NPC进入参与！ 253 255

[@Mir2m2地图收益关门]

#ACT

CALCVAR GLOBAL 地图收益判断 = 2

SAVEVAR GLOBAL 地图收益判断 ..\QuestDiary\Mir2m2开区清空文本(免费脚本群.347979)\Mir2m2地图收益变量.txt

SENDMSG 0 【行会争霸】活动已经关门，清理完地图内非本行会的人即可获胜！ 253 255

[@Mir2m2地图收益结束]

#IF

CHECKVAR GLOBAL 地图收益判断 = 2

#ACT

CALCVAR GLOBAL 地图收益判断 = 0

SAVEVAR GLOBAL 地图收益判断 ..\QuestDiary\Mir2m2开区清空文本(免费脚本群.347979)\Mir2m2地图收益变量.txt

SENDMSG 0 【行会争霸】活动已经结束，本次活动无行会获胜！ 253 255

GMEXECUTE $(地图收益触发) @Mir2m2地图收益结束清人

[@Mir2m2地图收益常量加载]

#CALL [\Mir2m2地图收益配置(免费脚本群.347979)\Mir2m2地图收益常量.ini] @Mir2m2地图收益常量

}

[@Mir2m2地图收益脚本QM]

{

[@Mir2m2地图收益结束清人]

#IF

ISONMAP Mir2m2_SHOUYI

#ACT

MAPMOVE 3 330 330

MESSAGEBOX 本次行会争霸活动已结束！

BREAK

}